pm_arrayRefill Module Reference

This module contains procedures and generic interfaces for resizing allocatable arrays of various types, relocating their contents and filling the newly added elements with specific values. More...

Data Types
interface	setRefilled
	Allocate or resize (shrink or expand) and refill an input allocatable scalar string or array of rank 1..3 to an arbitrary size while preserving the original contents or a subset of it. More...

Variables
character(*, SK), parameter	MODULE_NAME = "@pm_arrayRefill"

Detailed Description

This module contains procedures and generic interfaces for resizing allocatable arrays of various types, relocating their contents and filling the newly added elements with specific values.

In brief,

1. Use setResized to resize strings/arrays without changing the lower bound.
   The following figure illustrates example resizing of a 1D array and transferal of its contents.
   
   
   
2. Use setRefilled to resize strings/arrays without changing the lower bound and to initialize the new elements.
   The following figure illustrates example refilling of a 1D array and transferal of its contents.
   
   
   
3. Use setRebound to resize arrays by changing their lower and/or upper bounds.
   The following figure illustrates example rebinding of a 1D array and transferal of its contents.
   
   
   
4. Use setRebilled to resize arrays by changing their lower and/or upper bounds and to initialize the new elements.
   The following figure illustrates example rebinding and refilling of a 1D array and transferal of its contents.
   
   
   

Benchmarks:

Benchmark :: The runtime performance of setRefilled vs. direct reversing ⛓

program benchmark
 
    use iso_fortran_env, only: error_unit
    use pm_bench, only: bench_type
    use pm_kind, only: IK, RK, SK
 
    implicit none
 
    integer(IK)                         :: i
    integer(IK)                         :: isize
    integer(IK)                         :: fileUnit
    integer(IK) , parameter             :: NSIZE = 21_IK
    integer(IK) , parameter             :: NBENCH = 2_IK
    integer(IK)                         :: arraySize(NSIZE)
    real(RK)                            :: dummy = 0._RK
    real(RK)    , allocatable           :: array(:)
    type(bench_type)                    :: bench(NBENCH)
 
    bench(1) = bench_type(name = SK_"setRefilled", exec = setRefilled , overhead = setOverhead)
    bench(2) = bench_type(name = SK_"direct", exec = direct , overhead = setOverhead)
 
    arraySize = [( 2_IK**isize, isize = 1_IK, NSIZE )]
 
    write(*,"(*(g0,:,' '))")
    write(*,"(*(g0,:,' '))") "setRefilled() vs. direct()"
    write(*,"(*(g0,:,' '))")
 
    open(newunit = fileUnit, file = "main.out", status = "replace")
 
        write(fileUnit, "(*(g0,:,','))") "arraySize", (bench(i)%name, i = 1, NBENCH)
 
        loopOverArraySize: do isize = 1, NSIZE - 1
 
            write(*,"(*(g0,:,' '))") "Benchmarking with size", arraySize(isize)
 
            allocate(array(arraySize(isize)))
            call random_number(array)
            do i = 1, NBENCH
                bench(i)%timing = bench(i)%getTiming(minsec = 0.1_RK, miniter = 20_IK)
            end do
            deallocate(array)
 
            write(fileUnit,"(*(g0,:,','))") arraySize(isize), (bench(i)%timing%mean, i = 1, NBENCH)
 
        end do loopOverArraySize
        write(*,"(*(g0,:,' '))") dummy
        write(*,"(*(g0,:,' '))")
 
    close(fileUnit)
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead()
        call initialize()
        call finalize()
    end subroutine
 
    subroutine initialize()
        use pm_arrayShuffle, only: setShuffled
        call setShuffled(array(1:arraySize(isize)))
    end subroutine
 
    subroutine finalize()
        dummy = dummy + array(1)
    end subroutine
 
    subroutine setRefilled()
        block
            use pm_arrayRefill, only: setRefilled
            call initialize()
                call setRefilled(array, 0._RK, arraySize(isize+1))
            call finalize()
        end block
    end subroutine
 
    subroutine direct()
        real(RK), allocatable :: Temp(:)
        call initialize()
            Temp = array(1:arraySize(isize))
            deallocate(array)
            allocate(array(arraySize(isize+1)))
            array(1:arraySize(isize)) = Temp
            array(arraySize(isize)+1:arraySize(isize+1)) = 0._RK
        call finalize()
        deallocate(Temp)
    end subroutine
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
fontsize = 14
 
methods = ["setRefilled", "direct"]
 
df = pd.read_csv("main.out")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for method in methods:
    plt.plot( df["arraySize"].values
            , df[method].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Array Size", fontsize = fontsize)
ax.set_ylabel("Runtime [ seconds ]", fontsize = fontsize)
ax.set_title("setRefilled() vs. direct method.\nLower is better.", fontsize = fontsize)
ax.set_xscale("log")
ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( methods
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark.setRefilled_vs_direct.runtime.png")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
plt.plot( df["arraySize"].values
        , np.ones(len(df["arraySize"].values))
        , linestyle = "-"
        , linewidth = 2
        )
plt.plot( df["arraySize"].values
        , df["direct"].values / df["setRefilled"].values
        , linewidth = 2
        )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Array Size", fontsize = fontsize)
ax.set_ylabel("Runtime compared to setRefilled()", fontsize = fontsize)
ax.set_title("direct method to setRefilled() Runtime Ratio.\nLower means faster. Lower than 1 means faster than setRefilled().", fontsize = fontsize)
ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( ["setRefilled()", "Direct Method"]
           #, bbox_to_anchor = (1, 0.5)
           #, loc = "center left"
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark.setRefilled_vs_direct.runtime.ratio.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. The procedures under the generic interface setRefilled are about \(\ms{10-20%}\) faster than naively copying and resizing via temporary arrays and initializing the values, simply because setRefilled avoids an extra unnecessary reallocation and data copy.
   

Test:

test_pm_arrayRefill

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Fatemeh Bagheri, Wednesday 12:20 AM, October 13, 2021, Dallas, TX

Variable Documentation

MODULE_NAME

character(*,SK), parameter pm_arrayRefill::MODULE_NAME = "@pm_arrayRefill"

Definition at line 85 of file pm_arrayRefill.F90.