pm_arrayRemap Module Reference

This module contains procedures and generic interfaces for remapping arrays of various types. More...

Data Types
interface	getRemapped
	Generate a copy of the input array whose elements are reordered according to the input index array such that,   arrayNew = array(index) or,   arrayNew = array(index(size(index):1:-1)) if action = reverse or, holds for the output. More...
interface	setRemapped
	Reorder the elements of the input array according to the input index array, such that   array = array(index) or,   array = array(index(size(index):1:-1)) if action = reverse or,   arrayNew = array(index) if arrayNew is specified as input argument or,   arrayNew = array(index(size(index):1:-1)) if arrayNew and action = reverse are specified as input arguments, More...

Variables
character(*, SK), parameter	MODULE_NAME = "@pm_arrayRemap"

Detailed Description

This module contains procedures and generic interfaces for remapping arrays of various types.

Benchmarks:

Benchmark :: The runtime performance of setRemapped vs. direct remapping ⛓

program benchmark
 
    use pm_kind, only: IK, LK, RK, SK
    use iso_fortran_env, only: error_unit
    use pm_arrayShuffle, only: setShuffled
    use pm_bench, only: bench_type
 
    implicit none
 
    integer(IK)                         :: i
    integer(IK)                         :: isize
    integer(IK)                         :: fileUnit
    integer(IK) , parameter             :: NSIZE = 15_IK
    integer(IK) , parameter             :: NBENCH = 3_IK
    integer(IK)                         :: arraySize(NSIZE)
    real(RK)                            :: dummy = 0._RK
    real(RK)    , allocatable           :: array(:)
    integer(IK) , allocatable           :: index(:)
    type(bench_type)                    :: bench(NBENCH)
 
    bench(1) = bench_type(name = SK_"setRemapped", exec = setRemapped, overhead = setOverhead)
    bench(2) = bench_type(name = SK_"getRemapped", exec = getRemapped, overhead = setOverhead)
    bench(3) = bench_type(name = SK_"direct", exec = direct , overhead = setOverhead)
 
    arraySize = [( 2_IK**isize, isize = 1_IK, NSIZE )]
 
    write(*,"(*(g0,:,' '))")
    write(*,"(*(g0,:,' '))") "setRemapped() vs. getRemapped() vs. direct()"
    write(*,"(*(g0,:,' '))")
 
    open(newunit = fileUnit, file = "main.out", status = "replace")
 
        write(fileUnit, "(*(g0,:,','))") "arraySize", (bench(i)%name, i = 1, NBENCH)
 
        loopOverArraySize: do isize = 1, NSIZE
 
            write(*,"(*(g0,:,' '))") "Benchmarking with size", arraySize(isize)
 
            index = [( i, i = 1, arraySize(isize) )]
            allocate(array(arraySize(isize)))
            call random_number(array)
            call setShuffled(index)
            do i = 1, NBENCH
                bench(i)%timing = bench(i)%getTiming(minsec = 0.07_RK)
            end do
            deallocate(array)
 
            write(fileUnit,"(*(g0,:,','))") arraySize(isize), (bench(i)%timing%mean, i = 1, NBENCH)
 
        end do loopOverArraySize
        write(*,"(*(g0,:,' '))") dummy
        write(*,"(*(g0,:,' '))")
 
    close(fileUnit)
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead()
        call finalize()
    end subroutine
 
    subroutine finalize()
        dummy = dummy + array(1)
    end subroutine
 
    subroutine setRemapped()
        block
            use pm_arrayRemap, only: setRemapped, reverse
            call setRemapped(array, index, reverse)
            call finalize()
        end block
    end subroutine
 
    subroutine getRemapped()
        block
            use pm_arrayRemap, only: getRemapped, reverse
            array = getRemapped(array, index, reverse)
            call finalize()
        end block
    end subroutine
 
    subroutine direct()
        array = array(index(arraySize(isize):1:-1))
        call finalize()
    end subroutine
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
fontsize = 14
 
methods = ["setRemapped", "getRemapped", "direct"]
 
df = pd.read_csv("main.out")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for method in methods:
    plt.plot( df["arraySize"].values
            , df[method].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Array Size", fontsize = fontsize)
ax.set_ylabel("Runtime [ seconds ]", fontsize = fontsize)
ax.set_title("setRemapped() vs. getRemapped() vs. direct method.\nLower is better.", fontsize = fontsize)
ax.set_xscale("log")
ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( methods
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark.setRemapped_getRemapped_direct.runtime.png")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
plt.plot( df["arraySize"].values
        , np.ones(len(df["arraySize"].values))
       #, linestyle = "--"
        , linewidth = 2
        )
plt.plot( df["arraySize"].values
        , df["getRemapped"].values / df["setRemapped"].values
        , linewidth = 2
        )
plt.plot( df["arraySize"].values
        , df["direct"].values / df["setRemapped"].values
        , linewidth = 2
        )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel("Array Size", fontsize = fontsize)
ax.set_ylabel("Runtime compared to setRemapped()", fontsize = fontsize)
ax.set_title("direct vs. getRemapped() to setRemapped() Runtime Ratio.\nLower means faster. Lower than 1 means faster than setRemapped().", fontsize = fontsize)
ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( ["setRemapped()", "getRemapped()", "Direct Method"]
           #, bbox_to_anchor = (1, 0.5)
           #, loc = "center left"
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark.setRemapped_getRemapped_direct.runtime.ratio.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. The procedures under the generic interface setRemapped tend to be significantly faster than directly remapping arrays. This likely only true for remapping of allocatable arrays.
   The primary reason for the better performance of setRemapped is that setRemapped avoids a final data copy from a dummy array to the original array by copying the allocation descriptor instead of the whole remapped array to the original array.
   
2. Note that the observed performance benefit slightly diminishes if the remapping is not in action = reverse mode.
   
3. The other benefit of setRemapped is that it provides a unified seamless generic interface for reversing all intrinsic types and kinds of arrays as well as assumed-length and assumed-shape characters.
   

Test:

test_pm_arrayRemap

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Fatemeh Bagheri, Wednesday 12:20 AM, October 13, 2021, Dallas, TX

Variable Documentation

MODULE_NAME

character(*, SK), parameter pm_arrayRemap::MODULE_NAME = "@pm_arrayRemap"

Definition at line 54 of file pm_arrayRemap.F90.