pm_arraySearch Module Reference

This module contains procedures and generic interfaces for finding the specific array index whose element has the largest value smaller than the input value in arrays of various types.
More...

Data Types
interface	getBin
	Generate and return bin, the index of the element of the input ascending-ordered array, such that array(bin) <= value < array(bin+1) holds for the input value. More...

Variables
character(*, SK), parameter	MODULE_NAME = "@pm_arraySearch"

Detailed Description

This module contains procedures and generic interfaces for finding the specific array index whose element has the largest value smaller than the input value in arrays of various types.

The input search array must be in ascending order.

Benchmarks:

Benchmark :: The runtime performance of getBin with and without isLess external optional input argument. ⛓

! Test the performance of getBin() with and without the optional external function `isLess` input argument.
program benchmark
 
    use iso_fortran_env, only: error_unit
    use pm_kind, only: IK, LK, SK, RK, RKG => RKS
    use pm_distUnif, only: setUnifRand
    use pm_arraySpace, only: getLinSpace
    use pm_mathMinMax, only: getMinMax
    use pm_bench, only: bench_type
 
    implicit none
 
    integer(IK)                         :: i
    integer(IK)                         :: isize
    integer(IK)                         :: fileUnit
    integer(IK)     , parameter         :: NSIZE = 20_IK
    integer(IK)     , parameter         :: NBENCH = 2_IK
    integer(IK)                         :: arraySize(NSIZE)
    logical(LK)                         :: dummy = .true._LK
    real(RKG)         , allocatable     :: Array(:)
    real(RKG)                           :: value
    real(RKG)                           :: Limit(2)
    type(bench_type)                    :: bench(NBENCH)
    integer(IK)                         :: index, bin
    real(RK)                            :: MeanTime(2) = 0._RK
 
    bench(1) = bench_type(name = SK_"default"  , exec = default    , overhead = setOverhead)
    bench(2) = bench_type(name = SK_"isLessArg", exec = isLessArg  , overhead = setOverhead)
 
    arraySize = [( 2_IK**(isize+1), isize = 1_IK, NSIZE )]
 
    write(*,"(*(g0,:,' '))")
    write(*,"(*(g0,:,' '))") "isLessArg vs. default"
    write(*,"(*(g0,:,' '))")
 
    open(newunit = fileUnit, file = "main.out", status = "replace")
 
        write(fileUnit, "(*(g0,:,', '))") "arraySize", (bench(i)%name, i = 1, NBENCH)
 
        loopOverArraySize: do isize = 1, NSIZE
 
            write(*,"(*(g0,:,' '))") "Benchmarking with size", arraySize(isize)
 
            call random_number(Limit)
            Limit = getMinMax(Limit(1), Limit(2))
            Array = getLinSpace(Limit(1), Limit(2), count = arraySize(isize))
 
            do i = 1, NBENCH
                bench(i)%timing = bench(i)%getTiming(minsec = 0.03_RK)
                MeanTime(i) = MeanTime(i) + bench(i)%timing%mean
            end do
 
            do i = NBENCH, 1, -1
                bench(i)%timing = bench(i)%getTiming(minsec = 0.03_RK)
                MeanTime(i) = MeanTime(i) + bench(i)%timing%mean
            end do
 
            write(fileUnit,"(*(g0,:,', '))") arraySize(isize), MeanTime / 2
 
        end do loopOverArraySize
        write(*,"(*(g0,:,' '))") dummy
        write(*,"(*(g0,:,' '))")
 
    close(fileUnit)
 
contains
 
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
    ! procedure wrappers.
    !%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 
    subroutine setOverhead()
        call initialize()
        call finalize()
    end subroutine
 
    subroutine initialize()
        call setUnifRand(index, 1_IK, arraySize(isize))
        value = Array(index)
    end subroutine
 
    subroutine finalize()
        dummy = dummy .and. bin == index
    end subroutine
 
    subroutine isLessArg()
        use pm_arraySearch, only: getBin
        call initialize()
        bin = getBin(Array, value, isLess = isLess)
        call finalize()
    end subroutine
 
    subroutine default()
        use pm_arraySearch, only: getBin
        call initialize()
        bin = getBin(Array, value)
        call finalize()
    end subroutine
 
    pure function isLess(value, segment) result(less)
        use pm_kind, only: IK, LK
        integer(IK) , intent(in)    :: value, segment
        logical(LK)                 :: less
        less = value < segment
    end function
 
end program benchmark

Example Unix compile command via Intel ifort compiler ⛓

#!/usr/bin/env sh
rm main.exe
ifort -fpp -standard-semantics -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Example Windows Batch compile command via Intel ifort compiler ⛓

del main.exe
set PATH=..\..\..\lib;%PATH%
ifort /fpp /standard-semantics /O3 /I:..\..\..\include main.F90 ..\..\..\lib\libparamonte*.lib /exe:main.exe
main.exe

Example Unix / MinGW compile command via GNU gfortran compiler ⛓

#!/usr/bin/env sh
rm main.exe
gfortran -cpp -ffree-line-length-none -O3 -Wl,-rpath,../../../lib -I../../../inc main.F90 ../../../lib/libparamonte* -o main.exe
./main.exe

Postprocessing of the benchmark output ⛓

#!/usr/bin/env python
 
import matplotlib.pyplot as plt
import pandas as pd
import numpy as np
 
import os
dirname = os.path.basename(os.getcwd()) 
 
fontsize = 14
 
df = pd.read_csv("main.out", delimiter = ", ")
colnames = list(df.columns.values)
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
for colname in colnames[1:]:
    plt.plot( df[colnames[0]].values
            , df[colname].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel(colnames[0], fontsize = fontsize)
ax.set_ylabel("Runtime [ seconds ]", fontsize = fontsize)
ax.set_title(" vs. ".join(colnames[1:])+"\nLower is better.", fontsize = fontsize)
ax.set_xscale("log")
ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, loc='center left'
           #, bbox_to_anchor=(1, 0.5)
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.png")
 
 
 
ax = plt.figure(figsize = 1.25 * np.array([6.4,4.6]), dpi = 200)
ax = plt.subplot()
 
plt.plot( df[colnames[0]].values
        , np.ones(len(df[colnames[0]].values))
        , linestyle = "--"
       #, color = "black"
        , linewidth = 2
        )
for colname in colnames[2:]:
    plt.plot( df[colnames[0]].values
            , df[colname].values / df[colnames[1]].values
            , linewidth = 2
            )
 
plt.xticks(fontsize = fontsize)
plt.yticks(fontsize = fontsize)
ax.set_xlabel(colnames[0], fontsize = fontsize)
ax.set_ylabel("Runtime compared to {}".format(colnames[1]), fontsize = fontsize)
ax.set_title("Runtime Ratio Comparison. Lower means faster.\nLower than 1 means faster than {}().".format(colnames[1]), fontsize = fontsize)
ax.set_xscale("log")
#ax.set_yscale("log")
plt.minorticks_on()
plt.grid(visible = True, which = "both", axis = "both", color = "0.85", linestyle = "-")
ax.tick_params(axis = "y", which = "minor")
ax.tick_params(axis = "x", which = "minor")
ax.legend   ( colnames[1:]
           #, bbox_to_anchor = (1, 0.5)
           #, loc = "center left"
            , fontsize = fontsize
            )
 
plt.tight_layout()
plt.savefig("benchmark." + dirname + ".runtime.ratio.png")

Visualization of the benchmark output ⛓

Benchmark moral ⛓

1. The procedures under the generic interface getBin take an optional isLess() external-function input argument which can perform custom user-defined comparisons between the input value and array elements.
   By default, the comparison is the < operator.
   
2. The presence of an external isLess argument without inlining does appear to deteriorate the runtime performance of getBin.
   However, the exact amount of this penalty appears to significantly depend on the computing platform and the ability of the compiler to inline the external function.
   

Test:

test_pm_arraySearch

Final Remarks ⛓

---

If you believe this algorithm or its documentation can be improved, we appreciate your contribution and help to edit this page's documentation and source file on GitHub.
For details on the naming abbreviations, see this page.
For details on the naming conventions, see this page.
This software is distributed under the MIT license with additional terms outlined below.

1. If you use any parts or concepts from this library to any extent, please acknowledge the usage by citing the relevant publications of the ParaMonte library.
   
2. If you regenerate any parts/ideas from this library in a programming environment other than those currently supported by this ParaMonte library (i.e., other than C, C++, Fortran, MATLAB, Python, R), please also ask the end users to cite this original ParaMonte library.
   

This software is available to the public under a highly permissive license.
Help us justify its continued development and maintenance by acknowledging its benefit to society, distributing it, and contributing to it.

Copyright

Computational Data Science Lab

Author:

Fatemeh Bagheri, Wednesday 12:20 AM, October 13, 2021, Dallas, TX

Variable Documentation

MODULE_NAME

character(*,SK), parameter pm_arraySearch::MODULE_NAME = "@pm_arraySearch"

Definition at line 54 of file pm_arraySearch.F90.